copy chiaki ebuilds from guru repository

games-util/chiaki/Manifest

@@ -0,0 +1 @@
+DIST chiaki-2.1.1.tar.gz 6755442 BLAKE2B 6131b15d01b6ea96eedca0e8a3989bd353142ccc0fa34d159b1bf0a15412f315934b642f5e9e576dd8155506b85054000e54500e5966a3677bd60c989b2c9303 SHA512 3e0d8afd71f6f348d5ab0e68c7c46b9ee7d249d8b6b1185a746cb8b3907ea21db24756d5ec9de8debafbfffe74698358d29a97bc213cff7944ea15e894c3da50

games-util/chiaki/chiaki-2.1.1-r1.ebuild

@@ -0,0 +1,69 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..10} )
+inherit cmake python-single-r1 xdg
+
+DESCRIPTION="Client for PlayStation 4 and PlayStation 5 Remote Play"
+HOMEPAGE="https://git.sr.ht/~thestr4ng3r/chiaki"
+
+if [[ "${PV}" == "9999" ]] ; then
+	EGIT_REPO_URI="https://git.sr.ht/~thestr4ng3r/${PN}"
+	inherit git-r3
+else
+	SRC_URI="https://git.sr.ht/~thestr4ng3r/${PN}/refs/download/v${PV}/${PN}-v${PV}-src.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+	S="${WORKDIR}/${PN}"
+fi
+
+LICENSE="GPL-3"
+SLOT="0"
+IUSE="+cli +gui test"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	${PYTHON_DEPS}
+	dev-libs/jerasure
+	dev-libs/libevdev
+	dev-libs/openssl:=
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qtconcurrent:5
+	dev-qt/qtmultimedia:5
+	dev-qt/qtsvg:5
+	dev-qt/qtwidgets:5
+	media-libs/libsdl2
+	media-libs/opus
+	media-video/ffmpeg:=
+"
+
+DEPEND="${RDEPEND}"
+
+BDEPEND="
+	${PYTHON_DEPS}
+	$(python_gen_cond_dep 'dev-python/protobuf-python[${PYTHON_USEDEP}]')
+	dev-libs/protobuf
+	virtual/pkgconfig
+"
+
+src_configure() {
+	local mycmakeargs=(
+		-DPYTHON_EXECUTABLE="${PYTHON}"
+		-DCHIAKI_USE_SYSTEM_JERASURE=TRUE
+		-DCHIAKI_ENABLE_TESTS=$(usex test)
+		-DCHIAKI_ENABLE_CLI=$(usex cli)
+		-DCHIAKI_ENABLE_GUI=$(usex gui)
+	)
+
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+
+	dolib.so "${BUILD_DIR}"/lib/*.so
+	dolib.so "${BUILD_DIR}"/setsu/*.so
+}

games-util/chiaki/chiaki-9999.ebuild

@@ -1,40 +1,69 @@
-# Copyright 2021 Gentoo Authors
+# Copyright 1999-2022 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=7
+EAPI=8
 
-inherit cmake
+PYTHON_COMPAT=( python3_{8..10} )
+inherit cmake python-single-r1 xdg
 
-if [[ ${PV} == *9999 ]]; then
+DESCRIPTION="Client for PlayStation 4 and PlayStation 5 Remote Play"
-	inherit git-r3
-	EGIT_REPO_URI="https://git.sr.ht/~thestr4ng3r/chiaki"
-	KEYWORDS="~amd64"
-else
-	SRC_URI="https://git.sr.ht/~thestr4ng3r/chiaki/archive/v${PN}.tar.gz -> ${P}.tar.gz"
-	KEYWORDS="~amd64"
-fi
-
-DESCRIPTION="Chiaki is a client for PlayStation 4 and PlayStation 5 Remote Play"
 HOMEPAGE="https://git.sr.ht/~thestr4ng3r/chiaki"
 
-LICENSE="AGPL-3"
+if [[ "${PV}" == "9999" ]] ; then
-SLOT="0"
+	EGIT_REPO_URI="https://git.sr.ht/~thestr4ng3r/${PN}"
+	inherit git-r3
+else
+	SRC_URI="https://git.sr.ht/~thestr4ng3r/${PN}/refs/download/v${PV}/${PN}-v${PV}-src.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+	S="${WORKDIR}/${PN}"
+fi
 
-DEPEND="
+LICENSE="GPL-3"
-	dev-python/protobuf-python
+SLOT="0"
+IUSE="+cli +gui test"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	${PYTHON_DEPS}
+	dev-libs/jerasure
+	dev-libs/libevdev
+	dev-libs/openssl:=
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qtconcurrent:5
+	dev-qt/qtmultimedia:5
+	dev-qt/qtsvg:5
+	dev-qt/qtwidgets:5
+	media-libs/libsdl2
+	media-libs/opus
+	media-video/ffmpeg:=
+"
+
+DEPEND="${RDEPEND}"
+
+BDEPEND="
+	${PYTHON_DEPS}
+	$(python_gen_cond_dep 'dev-python/protobuf-python[${PYTHON_USEDEP}]')
+	dev-libs/protobuf
+	virtual/pkgconfig
 "
-RDEPEND="${DEPEND}"
-BDEPEND=""
 
 src_configure() {
 	local mycmakeargs=(
-		-DCMAKE_POSITION_INDEPENDENT_CODE=ON
+		-DPYTHON_EXECUTABLE="${PYTHON}"
+		-DCHIAKI_USE_SYSTEM_JERASURE=TRUE
+		-DCHIAKI_ENABLE_TESTS=$(usex test)
+		-DCHIAKI_ENABLE_CLI=$(usex cli)
+		-DCHIAKI_ENABLE_GUI=$(usex gui)
 	)
+
 	cmake_src_configure
 }
 
 src_install() {
 	cmake_src_install
-	dolib.so ${WORKDIR}/chiaki-9999_build/lib/libchiaki.so
+
-	dolib.so ${WORKDIR}/chiaki-9999_build/setsu/libsetsu.so
+	dolib.so "${BUILD_DIR}"/lib/*.so
+	dolib.so "${BUILD_DIR}"/setsu/*.so
 }

games-util/chiaki/metadata.xml

@@ -0,0 +1,16 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<email>vowstar@gmail.com</email>
+		<name>Huang Rui</name>
+	</maintainer>
+	<use>
+		<flag name="cli">Build CLI interface</flag>
+	</use>
+	<longdescription lang="en">
+	Chiaki is a Free and Open Source Software Client for PlayStation 4 and
+	PlayStation 5 Remote Play for Linux, FreeBSD, OpenBSD, Android, macOS,
+	Windows, Nintendo Switch and potentially even more platforms.
+	</longdescription>
+</pkgmetadata>